English
Español
Identificador de Regra
VEN-140CTE0001
Módulo: VEN - Vendas.
Finalidade: Manipular informações do conhecimento de transporte da versão 3.0 ou superior antes da geração do arquivo XML.
Características:
- Contém campos que podem se repetir, podem ser informados separados pelo caractere determinado pela variável VenASeparador. Se esta variável não for informada, o separador padrão será ";" (ponto e vírgula). Os campos onde será possível esse tratamento, estarão identificados por n no início de sua descrição;
- Para gerar o grupo dos Dados Complementares é necessário que um dos registros a seguir tenham um valor: As variáveis são: VenASigPas, VenACadTnp, VenACadSer, VenAFunEmi, VenASigOri, VenASigDes, VenACrtEnt;
- Para que alguns campos sejam gerados no conhecimento de transporte é necessário que outros também sejam gerados. Por exemplo: Para que o campo do grupo Dados dos Veículos seja impresso é necessário que os demais campos deste grupo também sejam impressos, conforme manual de integração do CT-e;
- As variáveis que aceitam retorno da regra devem ser utilizadas conforme manual do contribuinte pode ocorrer erros na emissão ou validação do arquivo caso isso não seja respeitado;
- Quando utilizadas variáveis do tipo alfa que tratam valores (R$), como a VenAOutVlr, deve ser tomado um cuidado adicional para não alterar o VenASeparador para utilizar a virgula (,) ou ponto (.). Pois nos casos de valores a virgula e o ponto são utilizados como separador. Dessa forma não será possível extrair os dados do retorno, resultando em erros. Ao alterar a variável VenASeparador, todas as variáveis com dados alterados deverão ser reconstruídas com o novo separador;
- Quando for utilizado um separador seguido de outro, indica-se o envio "vazio";
- As variáveis referente à observação do CT-e: VenAObsGer, VenAObcCmp e VenAObcTxt. Para serem enviadas ao arquivo XML os valores das variáveis, é necessário que uma das seguintes variáveis seja declarada e tenha valor definido: VenACadTnp, VenACadSer, VenAFunEmi, VenASigOri, VenASigPas, VenASigDes e VenACrtEnt.
- Os campos VenACmvNom e VenACmvVlr permitem o retorno de um ou mais valores para o sistema.
- Abaixo, através do exemplo de regra 3, é possível verificar como deve ser o retorno das variáveis contendo mais de um valor.
Tela: F140COL.
Web service: com.senior.g5.co.mcm.ven.conhecimentotransporte, porta GravarCTRC_2.
Transação: Não se aplica.
Regras:
Exemplo 1:
Definir Alfa VenSeparador;
/* VenSeparador = ";"; */ /* Este é o padrão, mas pode ser mudado. Ex.: "|","/","-"... */
/* Se for utilizar o padrão, não precisa declarar a variável */
/* Evitar de utilizar a virgula (,) e o ponto (.) como separador*/
/* Se for alterado o separador, as váriaveis de retorno deverão ser reconstruídas com o novo separador */
VenSeparador = ";";
/* Variáveis da composição do CTe */
Definir Alfa VenASeqCct;
/* Variáveis da unidade de transporte */
Definir Alfa VenACctUnt;
Definir Alfa VenASeqUnt;
Definir Alfa VenATipUnt;
Definir Alfa VenACodIdt;
Definir Alfa VenARatUnt;
/* Variáveis da unidade de carga */
Definir Alfa VenACctUnc;
Definir Alfa VenAUntUnc;
Definir Alfa VenASeqUnc;
Definir Alfa VenATipUnc;
Definir Alfa VenACodIdc;
Definir Alfa VenARatUnc;
/* Variáveis dos lacres */
Definir Alfa VenACctLac;
Definir Alfa VenAUntLac;
Definir Alfa VenAUncLac;
Definir Alfa VenACodLac;
/* Variáveis para manipulação, não retornam valores */
Definir Alfa xLinha;
Definir Numero xPos;
Definir Numero xTam;
Definir Numero xNSeqCct;
Definir Alfa xASeqCct;
Definir Numero xNSeqUnt;
Definir Alfa xASeqUnt;
Definir Numero xNSeqUnc;
Definir Alfa xASeqUnc;
Definir Numero xNRat;
Definir Alfa xARat;
Definir Alfa xALac;
/* Limpa as variáveis, ou seja, caso tenha informações vindas do CTe,
ignora e incluí no xml apenas as definidas aqui na regra*/
VenACctUnt = "";
VenASeqUnt = "";
VenATipUnt = "";
VenACodIdt = "";
VenARatUnt = "";
VenACctUnc = "";
VenAUntUnc = "";
VenASeqUnc = "";
VenATipUnc = "";
VenACodIdc = "";
VenARatUnc = "";
VenACctLac = "";
VenAUntLac = "";
VenAUncLac = "";
VenACodLac = "";
xNSeqUnt = 0;
xNSeqUnc = 0;
xPos = 1;
xLinha = VenASeqCct;
/*Percorre todas as composições*/
enquanto (xPos > 0)
inicio
PosicaoAlfa(VenSeparador, xLinha, xPos);
se (xPos > 0)
inicio
/*Pega o primeiro número*/
xPos = xPos - 1;
xASeqCct = xLinha;
CopiarAlfa(xASeqCct, 1, xPos);
/*Remove o número já tratado*/
xPos = xPos + 2;
TamanhoAlfa(xLinha, xTam);
CopiarAlfa(xLinha, xPos, xTam);
fim
senao
xASeqCct = xLinha;
AlfaParaInt(xASeqCct, xNSeqCct);
/* Adiciona uma unidade de transporte para cada composição */
xNSeqUnt = xNSeqUnt + 1;
IntParaAlfa(xNSeqUnt, xASeqUnt);
xNRat = xNSeqUnt * 10 / 3;
ArredondarValor(xNRat, 2);
DecimalParaAlfa(xNRat, xARat);
VenACctUnt = VenACctUnt + VenSeparador + xASeqCct;
VenASeqUnt = VenASeqUnt + VenSeparador + xASeqUnt;
VenATipUnt = VenATipUnt + VenSeparador + "1";
VenACodIdt = VenACodIdt + VenSeparador + "ERP000" + xASeqUnt;
VenARatUnt = VenARatUnt + VenSeparador + xARat;
/* Adiciona um lacre a unidade de transporte */
ConverteMascara(1, xNSeqCct, xARat, "9999");
xALac = "CCT" + xARat;
ConverteMascara(1, xNSeqUnt, xARat, "9999");
xALac = xALac + "UNT" + xARat + "LAC001";
VenACctLac = VenACctLac + VenSeparador + xASeqCct;
VenAUntLac = VenAUntLac + VenSeparador + xASeqUnt;
VenAUncLac = VenAUncLac + VenSeparador + "0";
VenACodLac = VenACodLac + VenSeparador + xALac;
/* Adiciona uma unidade de carga */
xNSeqUnc = xNSeqUnc + 1;
IntParaAlfa(xNSeqUnc, xASeqUnc);
xNRat = xNRat / 3;
ArredondarValor(xNRat, 2);
DecimalParaAlfa(xNRat, xARat);
VenACctUnc = VenACctUnc + VenSeparador + xASeqCct;
VenAUntUnc = VenAUntUnc + VenSeparador + xASeqUnt;
VenASeqUnc = VenASeqUnc + VenSeparador + xASeqUnc;
VenATipUnc = VenATipUnc + VenSeparador + "1";
VenACodIdc = VenACodIdc + VenSeparador + "MER000" + xASeqUnc;
VenARatUnc = VenARatUnc + VenSeparador + xARat;
/* Adiciona um lacre a unidade de carga */
ConverteMascara(1, xNSeqCct, xARat, "9999");
xALac = "CCT" + xARat;
ConverteMascara(1, xNSeqUnc, xARat, "9999");
xALac = xALac + "UNC" + xARat + "LAC002";
VenACctLac = VenACctLac + VenSeparador + xASeqCct;
VenAUntLac = VenAUntLac + VenSeparador + "0";
VenAUncLac = VenAUncLac + VenSeparador + xASeqUnc;
VenACodLac = VenACodLac + VenSeparador + xALac;
/* Adiciona outra unidade de carga */
xNSeqUnc = xNSeqUnc + 1;
IntParaAlfa(xNSeqUnc, xASeqUnc);
xNRat = xNRat * 2;
ArredondarValor(xNRat, 2);
DecimalParaAlfa(xNRat, xARat);
VenACctUnc = VenACctUnc + VenSeparador + xASeqCct;
VenAUntUnc = VenAUntUnc + VenSeparador + xASeqUnt;
VenASeqUnc = VenASeqUnc + VenSeparador + xASeqUnc;
VenATipUnc = VenATipUnc + VenSeparador + "1";
VenACodIdc = VenACodIdc + VenSeparador + "MER000" + xASeqUnc;
VenARatUnc = VenARatUnc + VenSeparador + xARat;
/* Adiciona um lacre a outra unidade de carga */
ConverteMascara(1, xNSeqCct, xARat, "9999");
xALac = "CCT" + xARat;
ConverteMascara(1, xNSeqUnc, xARat, "9999");
xALac = xALac + "UNC" + xARat + "LAC003";
VenACctLac = VenACctLac + VenSeparador + xASeqCct;
VenAUntLac = VenAUntLac + VenSeparador + "0";
VenAUncLac = VenAUncLac + VenSeparador + xASeqUnc;
VenACodLac = VenACodLac + VenSeparador + xALac;
/* Adiciona outro lacre a outra unidade de carga */
ConverteMascara(1, xNSeqCct, xARat, "9999");
xALac = "CCT" + xARat;
ConverteMascara(1, xNSeqUnc, xARat, "9999");
xALac = xALac + "UNC" + xARat + "LAC004";
VenACctLac = VenACctLac + VenSeparador + xASeqCct;
VenAUntLac = VenAUntLac + VenSeparador + "0";
VenAUncLac = VenAUncLac + VenSeparador + xASeqUnc;
VenACodLac = VenACodLac + VenSeparador + xALac;
fim
/* Remove o primeiro separador, necessário caso as variáveis sejam limpas no início ou venham em vazias */
Definir Numero xTse;
TamanhoAlfa(VenSeparador, xTse);
xTse = xTse + 1;
TamanhoAlfa(VenACctUnt, xTam);
CopiarAlfa(VenACctUnt, xTse, xTam);
TamanhoAlfa(VenASeqUnt, xTam);
CopiarAlfa(VenASeqUnt, xTse, xTam);
TamanhoAlfa(VenATipUnt, xTam);
CopiarAlfa(VenATipUnt, xTse, xTam);
TamanhoAlfa(VenACodIdt, xTam);
CopiarAlfa(VenACodIdt, xTse, xTam);
TamanhoAlfa(VenARatUnt, xTam);
CopiarAlfa(VenARatUnt, xTse, xTam);
TamanhoAlfa(VenACctUnc, xTam);
CopiarAlfa(VenACctUnc, xTse, xTam);
TamanhoAlfa(VenAUntUnc, xTam);
CopiarAlfa(VenAUntUnc, xTse, xTam);
TamanhoAlfa(VenASeqUnc, xTam);
CopiarAlfa(VenASeqUnc, xTse, xTam);
TamanhoAlfa(VenATipUnc, xTam);
CopiarAlfa(VenATipUnc, xTse, xTam);
TamanhoAlfa(VenACodIdc, xTam);
CopiarAlfa(VenACodIdc, xTse, xTam);
TamanhoAlfa(VenARatUnc, xTam);
CopiarAlfa(VenARatUnc, xTse, xTam);
TamanhoAlfa(VenACctLac, xTam);
CopiarAlfa(VenACctLac, xTse, xTam);
TamanhoAlfa(VenAUntLac, xTam);
CopiarAlfa(VenAUntLac, xTse, xTam);
TamanhoAlfa(VenAUncLac, xTam);
CopiarAlfa(VenAUncLac, xTse, xTam);
TamanhoAlfa(VenACodLac, xTam);
CopiarAlfa(VenACodLac, xTse, xTam);
Exemplo 2:
Definir Alfa VenSeparador;
/* VenSeparador = ";"; */ /* Este é o padrão, mas pode ser mudado. Ex.: "|","/","-"... */
/* Se for utilizar o padrão, não precisa declarar a variável */
/* Evitar de utilizar a virgula (,) e o ponto (.) como separador*/
/* Se for alterado o separador, as váriaveis de retorno deverão ser reconstruídas com o novo separador */
VenSeparador = ";";
Definir Alfa VenASeqCct;
Definir Alfa VenACctUnc;
Definir Alfa VenASeqUnc;
Definir Alfa VenACctLac;
Definir Alfa VenAUntLac;
Definir Alfa VenAUncLac;
Definir Alfa VenACodLac;
Definir Alfa xLinha;
Definir Alfa xLinhaC;
Definir Alfa xLinhaS;
Definir Alfa xDados;
Definir Alfa xASeqCct;
Definir Alfa xASeqUnc;
Definir Numero xPos;
Definir Numero xPCct;
Definir Numero xPUnc;
Definir Numero xTam;
Definir Numero xSeqCct;
Definir Numero xCctUnc;
Definir Numero xSeqUnc;
xPos = 1;
xLinha = VenASeqCct;
/*Percorre todas as composições*/
enquanto (xPos > 0)
inicio
PosicaoAlfa(VenSeparador, xLinha, xPos);
se (xPos > 0)
inicio
/*Pega o primeiro número*/
xPos = xPos - 1;
xDados = xLinha;
CopiarAlfa(xDados, 1, xPos);
/*Remove o número já tratado*/
xPos = xPos + 2;
TamanhoAlfa(xLinha, xTam);
CopiarAlfa(xLinha, xPos, xTam);
fim
senao
xDados = xLinha;
AlfaParaInt(xDados, xSeqCct);
xPCct = 1;
xLinhaC = VenACctUnc;
xLinhaS = VenASeqUnc;
/*percorre todas as unidades de carga*/
enquanto (xPCct > 0)
inicio
PosicaoAlfa(VenSeparador, xLinhaC, xPCct);
se (xPCct > 0)
inicio
/*Pega a sequencia da composição da unidade de carga*/
xPCct = xPCct - 1;
xDados = xLinhaC;
CopiarAlfa(xDados, 1, xPCct);
/*Remove a sequencia tratada*/
xPCct = xPCct + 2;
TamanhoAlfa(xLinhaC, xTam);
CopiarAlfa(xLinhaC, xPCct, xTam);
AlfaParaInt(xDados, xCctUnc);
/*pega a sequencia da unidade de carga*/
PosicaoAlfa(VenSeparador, xLinhaS, xPUnc);
xPUnc = xPUnc - 1;
xDados = xLinhaS;
CopiarAlfa(xDados, 1, xPUnc);
/*Remove a sequencia tratada*/
xPUnc = xPUnc + 2;
TamanhoAlfa(xLinhaS, xTam);
CopiarAlfa(xLinhaS, xPUnc, xTam);
AlfaParaInt(xDados, xSeqUnc);
fim
senao
inicio
AlfaParaInt(xLinhaC, xCctUnc);
AlfaParaInt(xLinhaS, xSeqUnc);
fim
/*Se for a mesma sequencia da composicao, adiciona um lacre a unidade de carga*/
se (xCctUnc = xSeqCct)
inicio
IntParaAlfa(xCctUnc, xDados);
VenACctLac = VenACctLac + VenSeparador + xDados;
VenAUntLac = VenAUntLac + VenSeparador + "0";
IntParaAlfa(xSeqUnc, xDados);
VenAUncLac = VenAUncLac + VenSeparador + xDados;
ConverteMascara(1, xCctUnc, xASeqCct, "99999");
ConverteMascara(1, xSeqUnc, xASeqUnc, "99999");
VenACodLac = VenACodLac + VenSeparador + "8888888888" + xASeqCct + xASeqUnc;
fim
fim
fim
Exemplo 3:
Definir alfa VenACmvNom;
Definir alfa VenACmvVlr;
VenACmvNom = "Teste;Alou";
VenACmvVlr = "2530;1025";
Variáveis Disponibilizadas:
| Nome | Tipo | Observações | Retorna Valor |
|---|---|---|---|
| VenNCodEmp | NÚMERO | Código da empresa do CT-e. | N |
| VenNCodFil | NÚMERO | Código da filial do CT-e. | N |
| VenNNumNfv | NÚMERO | Número do conhecimento de transporte eletrônico. | N |
| VenACodSnf | ALFA | Código da série do conhecimento de transporte eletrônico. | N |
| VenASeparador | ALFA | Caractere separador. | S |
| VenAVerSao | ALFA | Versão de integração do CT-e (1.04, 2.00, 3.00) | N |
| VenASigUfs | ALFA | ide - Código da UF do emitente do CT-e | S |
| VenANopSer | ALFA | ide - Código fiscal de operações e prestações | S |
| VenANatOpe | ALFA | ide - Natureza da operação | S |
| VenAModDcf | ALFA | ide - Modelo do documento fiscal | S |
| VenNTipImp | NÚMERO | ide - Formato de impressão do DACTE. 1 - Retrato; 2 - Paisagem | S |
| VenNTipEmi | NÚMERO | ide - Forma de emissão do CT-e. 1 - Normal; 2 - Contingência | S |
| VenNTipAmb | NÚMERO | ide - Tipo do ambiente. 1 - Produção; 2 - Homologação | S |
| VenNTipCte | NÚMERO | ide - Tipo do CT-e. 0 - CT-e Normal; 1 - CT-e de Complemento de Valores; 2 - CT-e de Anulação de Valores; 3 - CT-e Substituto | S |
| VenNPrcEmi | NÚMERO | ide - Identificador do processo de emissão do CT-e.
0 - emissão de CT-e com aplicativo do contribuinte; 1 - emissão de CT-e avulsa pelo Fisco; 2 - emissão de CT-e avulsa, pelo contribuinte com seu certificado digital, através do site do Fisco; 3- emissão CT-e pelo contribuinte com aplicativo fornecido pelo Fisco. |
S |
| VenAVerPrc | ALFA | ide - Versão do processo de emissão. | S |
| VenNCmuEmi | NÚMERO | ide - Código do município onde o CT-e está sendo emitido | S |
| VenANmuEmi | ALFA | ide - Nome do município onde o CT-e está sendo emitido | S |
| VenAUfsEmi | ALFA | ide - Sigla da UF onde o CT-e está sendo emitido | S |
| VenAMdlCte | ALFA | ide - Modal: 01-Rodoviário; 02-Aéreo; 03-Aquaviário; 04-Ferroviário; 05-Dutoviário; 06-MultiModal | S |
| VenNTipSrv | NÚMERO | ide - Tipo do Serviço: 0 - Normal; 1 - Subcontratação; 2 - Redespacho; 3 - Redespacho Intermediário; 4 - Serviço Vinculado MultiModal | S |
| VenNCmuIni | NÚMERO | ide - Código do município de início da prestação | S |
| VenANmuIni | ALFA | ide - Nome do município do início da prestação | S |
| VenAUfsIni | ALFA | ide - UF do início da prestação | S |
| VenNCmuFim | NÚMERO | ide - Código do município de término da prestação | S |
| VenANmuFim | ALFA | ide - Nome do município do término da prestação | S |
| VenAUfsFim | ALFA | ide - UF do término da prestação | S |
| VenNIndRet | NÚMERO | ide - Indicador se o recebedor retira no aeroporto, filial, porto ou estação de destino. 0 - sim; 1 - não | S |
| VenADesRet | ALFA | ide - Detalhes do retira | S |
| VenNDesCgc | NÚMERO | toma - Número do CNPJ ou CPF | S |
| VenANomTom | ALFA | toma - Razão social ou nome | S |
| VenAFntTom | ALFA | toma - Nome fantasia | S |
| VenAFonTom | ALFA | toma - Telefone | S |
| VenALgrTom | ALFA | enderToma - Logradouro | S |
| VenANroTom | ALFA | enderToma - Número | S |
| VenACplTom | ALFA | enderToma - Complemento | S |
| VenABaiTom | ALFA | enderToma - Complemento | S |
| VenABaiTom | ALFA | enderToma - Bairro | S |
| VenNCmuTom | NÚMERO | enderToma - Código do município | S |
| VenANmuTom | ALFA | enderToma - Nome do município | S |
| VenNCepTom | NÚMERO | enderToma - CEP | S |
| VenAUfsTom | ALFA | enderToma - Sigla da UF | S |
| VenACpaTom | ALFA | enderToma - Código do país | S |
| VenANpaTom | ALFA | enderToma - Nome do país | S |
| VenACadTnp | ALFA | compl - Característica adicional do transporte | S |
| VenACadSer | ALFA | compl - Característica adicional do serviço | S |
| VenAFunEmi | ALFA | compl - Funcionário emissor do CTe | S |
| VenASigOri | ALFA | fluxo - Sigla ou código interno da filial/porto/estação/aeroporto de origem | S |
| VenASigPas | ALFA | n - pass - Sigla ou código interno da filial/porto/estação/aeroporto de passagem | S |
| VenASigDes | ALFA | fluxo - Sigla ou código interno da filial/porto/estação/aeroporto de destino | S |
| VenACrtEnt | ALFA | fluxo - Código da rota de entrega | S |
| VenATipPen | ALFA | Entrega - Tipo de data/período programado para entrega | S |
| VenATipHen | ALFA | Entrega - Tipo de horário programado para entrega | S |
| VenDDatPrg | DATA | comData - Data programada | S |
| VenDDteIni | DATA | noPeriodo - Data inicial | S |
| VenDDteFim | DATA | noPeriodo - Data final | S |
| VenNHorPrg | NÚMERO | comHora - Hora programada | S |
| VenNHreIni | NÚMERO | noInter - Hora inicial | S |
| VenNHreFim | NÚMERO | noInter - Hora final | S |
| VenAOrgCft | ALFA | compl - Município de origem para efeito de cálculo do frete | S |
| VenADstCft | ALFA | compl - Município de destino para efeito de cálculo do frete | S |
| VenAObsGer | ALFA | compl - Observações gerais | S |
| VenAObcCmp | ALFA | n - compl - Observações do contribuinte - Campo de uso livre do contribuinte - Identificação do campo | S |
| VenAObcTxt | ALFA | n - compl - Observações do contribuinte - Campo de uso livre do contribuinte - Conteúdo do campo | S |
| VenAObfCmp | ALFA | n - compl - Observações do fisco - Campo de uso livre do contribuinte | S |
| VenAObfTxt | ALFA | n - compl - Observações do fisco - Campo de uso livre do contribuinte - Conteúdo do campo | S |
| VenALgrEmi | ALFA | enderEmit - Logradouro | S |
| VenANroEmi | ALFA | enderEmit - Número | S |
| VenACplEmi | ALFA | enderEmit - Complemento | S |
| VenABaiEmi | ALFA | enderEmit - Bairro | S |
| VenNCmuEmt | NÚMERO | enderEmit - Código do município | S |
| VenANmuEmt | ALFA | enderEmit - Nome do município | S |
| VenNCepEmt | NÚMERO | enderEmit - CEP | S |
| VenAUfsEmt | ALFA | enderEmit - Sigla da UF | S |
| VenAFonEmt | ALFA | enderEmit - Telefone | S |
| VenAFonRem | ALFA | rem - Telefone do remetente | S |
| VenALgrRem | ALFA | enderReme - Logradouro | S |
| VenANroRem | ALFA | enderReme - Número | S |
| VenACplRem | ALFA | enderReme - Complemento | S |
| VenABaiRem | ALFA | enderReme - Bairro | S |
| VenNCmuRem | ALFA | enderReme - Código do município | S |
| VenANmuRem | ALFA | enderReme - Nome do município | S |
| VenACepRem | ALFA | enderReme - CEP | S |
| VenAUfsRem | ALFA | enderReme - Sigla do Estado | S |
| VenAIesRem | ALFA | enderReme - Inscrição Estadual | S |
| VenACpaRem | ALFA | enderReme - Codigo do País | S |
| VenANpaRem | ALFA | enderReme - Nome do País | S |
| VenNImpExp | NÚMERO | Indicativo se imprime a tag <exped> (0-Não 1-Sim) | S |
| VenNCgcExp | NÚMERO | exped - Número do CNPJ/CPF | S |
| VenAIesExp | ALFA | exped - Inscrição estadual | S |
| VenANomExp | ALFA | exped - Razão social ou nome | S |
| VenAFonExp | ALFA | exped - Telefone | S |
| VenALgrExp | ALFA | enderExped - Logradouro | S |
| VenANroExp | ALFA | enderExped - Número | S |
| VenACplExp | ALFA | enderExped - Complemento | S |
| VenABaiExp | ALFA | enderExped - Bairro | S |
| VenNCmuExp | NÚMERO | enderExped - Código do município | S |
| VenANmuExp | ALFA | enderExped - Nome do município | S |
| VenACepExp | ALFA | enderExped - Cep | S |
| VenAUfsExp | ALFA | enderExped - UF | S |
| VenACpaExp | ALFA | enderExped - Código do país | S |
| VenANpaExp | ALFA | enderExped - Nome do país | S |
| VenAFonRec | ALFA | receb - Telefone | S |
| VenALgrRec | ALFA | enderReceb - Logradouro | S |
| VenANroRec | ALFA | enderReceb - Número | S |
| VenACplRec | ALFA | enderReceb - Complemento | S |
| VenABaiRec | ALFA | enderReceb - Bairro | S |
| VenNCmuRec | NÚMERO | enderReceb - Código do município | S |
| VenANmuRec | ALFA | enderReceb - Nome do município | S |
| VenACepRec | ALFA | enderReceb - CEP | S |
| VenAUfsRec | ALFA | enderReceb - UF | S |
| VenACpaRec | ALFA | enderReceb - Código do país | S |
| VenANpaRec | ALFA | enderReceb - Nome do país | S |
| VenAFonDst | ALFA | dest - Telefone | S |
| VenAIsuDst | ALFA | dest - Inscrição na SUFRAMA | S |
| VenALgrDst | ALFA | enderDest - Logradouro | S |
| VenANroDst | ALFA | enderDest - Número | S |
| VenACplDst | ALFA | enderDest - Complemento | S |
| VenABaiDst | ALFA | enderDest - Bairro | S |
| VenNCmuDst | NÚMERO | enderDest - Código do município | S |
| VenANmuDst | ALFA | enderDest - Nome do município | S |
| VenACepDst | ALFA | enderDest - CEP | S |
| VenAUfsDst | ALFA | enderDest - UF | S |
| VenACpaDst | ALFA | enderDest - Código do país | S |
| VenANpaDst | ALFA | enderDest - Nome do país | S |
| VenNTotTri | NÚMERO | imp -vTotTrib - Valor Total dos Impostos | S |
| VenACmvNom | ALFA | n - comp - Nome do componente | S |
| VenACmvVlr | ALFA | comp - Valor do componente | S |
| VenAInfAfi | ALFA | imp - Informações adicionais de interesse do Fisco | S |
| VenAProPre | ALFA | infCarga - Produto predominante | S |
| VenAOutCat | ALFA | infCarga - Outras características da carga | S |
| VenNVlrCav | NÚMERO | infCarga - Valor carga averbação | S |
| VenANrnTrc | ALFA | rodo - Registro nacional de transportadores rodoviários de carga | S |
| VenASerOcc | ALFA | occ - Série da OCC | S |
| VenAChsVei | ALFA | n - veicNovos - Chassi do veículo | S |
| VenACodCor | ALFA | n - veicNovos - Cor do veículo(código de cada montadora) | S |
| VenACorVei | ALFA | n - veicNovos - Descrição da cor do veículo | S |
| VenACodMar | ALFA | n - veicNovos - Código marca modelo | S |
| VenAVlrVei | ALFA | n - veicNovos - Valor unitário do veículo | S |
| VenAFrtVei | ALFA | n - veicNovos - Frete unitário do veículo | S |
| VenNVlrCre | NÚMERO | imp - ICMS - CST80 e CST90 - vCred - Valor do Crédito outorgado/Presumido | S |
| VenAOutDsc | ALFA | n - infOutros - Descrição quando se tratar de 99-Outros | S |
| VenAOutNum | ALFA | n - infOutros - Número | S |
| VenAOutEmi | ALFA | n - infOutros - Data de Emissão | S |
| VenAOutVlr | ALFA | n - infOutros - Valor do documento | S |
| VenAAutCPF | ALFA | n - autXML > CPF - CPF (apenas números) autorizado para download do XML | S |
| VenAAutCGC | ALFA | n - autXML > CNPJ - CNPJ (apenas números) autorizado para download do XML | S |
| VenACtgDat | ALFA | ide - Data da entrada em contingência | S |
| VenACtgJus | ALFA | ide - Justificativa da entrada em contingência | S |
| VenACifFob | ALFA | Forma de Pagamento do Serviço | N |
| VenANumMin | ALFA | aereo - nMinu - Número da Minuta | S |
| VenANumOca | ALFA | aereo - nOCA - Número Operacional do Conhecimento Aéreo | S |
| VenDDatPrv | DATA | aereo - dPrev - Data Prevista da Entrega | S |
| VenAClaTar | ALFA | aereo - CL - Classe (M- Taria Mínima, G- Tarifa Geral, E-Tarifa Específica) | S |
| VenACodTar | ALFA | aereo - cTar - Código da Tarifa | S |
| VenNVlrTar | NÚMERO | aereo - vTar - Valor da Tarifa | S |
| VenATamDim | ALFA | aereo - xDime - Dimensão | S |
| VenAInfMan | ALFA | n - aereo - cInfManu - Informação do Manuseio | S |
| VenASeqCct | ALFA | n - infDoc - Define as sequências da composição | N |
| VenACctUnt | ALFA | n - infUnidTransp - Sequência da composição da qual a unidade de transporte faz parte | S |
| VenASeqUnt | ALFA | n - infUnidTransp - Sequência da unidade de transporte (Id único na composição) | S |
| VenATipUnt | ALFA | n - infUnidTransp - tpUnidTransp - Tipo da Unidade de Transporte | S |
| VenACodIdt | ALFA | n - infUnidTransp - idUnidTransp - Identificação da Unidade de Transporte | S |
| VenARatUnt | ALFA | n - infUnidTransp - qtdRat - Quantidade rateada (Peso,Volume) | S |
| VenACctUnc | ALFA | n - infUnidCarga - Sequência da composição da qual a unidade de carga faz parte | S |
| VenAUntUnc | ALFA | n - infUnidCarga - Sequência da unidade de transporte da qual a unidade de carga faz parte | S |
| VenASeqUnc | ALFA | n - infUnidCarga - Sequência da unidade de carga (Id único na composição) | S |
| VenATipUnc | ALFA | n - infUnidCarga - tpUnidCarga - Tipo da Unidade de Carga | S |
| VenACodIdc | ALFA | n - infUnidCarga - idUnidCarga - Identificação da Unidade de Carga | S |
| VenARatUnc | ALFA | n - infUnidCarga - qtdRat - Quantidade rateada (Peso,Volume) | S |
| VenACctLac | ALFA | n - lacUnid - Sequência da composição da qual o lacre faz parte | S |
| VenAUntLac | ALFA | n - lacUnid - Sequência da unidade de transporte da qual o lacre faz parte (0 - se for ligado a uma unidade de carga) | S |
| VenAUncLac | ALFA | n - lacUnid - Sequência da unidade de carga da qual o lacre faz parte (0 - se for ligado a uma unidade de transporte) | S |
| VenACodLac | ALFA | n - lacUnid - nLacre - Número do lacre | S |
| VenAIesDs | ALFA | Dest - Inscrição Estadual Destinatário | S |
| VenAInsEst | ALFA | Toma - Inscrição Estadual Tomador | S |
| VenACmvNom | ALFA | Variável destinada a armazenar nomes. | S |
| VenACmvVlr | ALFA | Variável destinada a armazenar valores. | S |
Observação
Quando forem atribuídos mais de um valor às variáveis mencionadas, esses valores devem ser separados utilizando o caractere ";" (ponto e vírgula). Segue exemplo de atribuição:
VenACmvNom = "Informacao1; Informacao2";
VenACmvVlr = "1;2";
A estrutura gerada no arquivo XML será a seguinte:
<Comp>
<xNome>Informacao1</xNome>
<vComp>1</vComp>
</Comp>
<Comp>
<xNome>Informacao2</xNome>
<vComp>2</vComp>
</Comp>
Cada valor atribuído às variáveis VenACmvNom e VenACmvVlr será transformado em uma nova instância da tag <Comp>, com os respectivos valores atribuídos a <xNome> e <vComp>. Dessa forma, é importante garantir que o número de elementos em VenACmvNom e VenACmvVlr seja correspondente, pois cada posição nessas variáveis será usada para gerar uma tag <Comp> no XML.
Atenção
Caso o parâmetro global LisVarReg esteja habilitado, a variável ListaVariaveis estará disponível em todos os identificadores de regras do sistema. O conteúdo desta variável lista os campos disponibilizados no identificador de regras em questão.
Não é aconselhada a ativação desse parâmetro global para o uso cotidiano. Esse recurso de listagem dos campos de identificadores auxilia a construção de regras e o Suporte para, por exemplo, depuração ou quando não houver acesso à documentação dos identificadores de regras.
English
Español
